6 POKE53371,0:REM 20 MHZ IF SUPERCPU
8 DV=PEEK(186):IFDV<8THENDV=8
10 PRINT "[147]  [195]RYPTO [195]HALLENGE [211]OLUTION [199]ENERATOR"
20 PRINT " (PUZZLE ON [204][207][193][196][211][212][193][210] [201]SSUE 156 [196]ISK 2)"
30 PRINT TAB(7);"[208]ROGRAMMED BY [198]LOYD [210]. [203]IRK": PRINT
40 PRINT "[208]LACE A NEWLY FORMATTED DISK IN DRIVE 8."
50 PRINT "[211]OLUTIONS WILL BE GENERATED, SHOWN ON"
60 PRINT "THE SCREEN, AND STORED ON DISK IN A"
70 PRINT "SEQUENTIAL FILE (WHICH CAN BE READ BY A"
80 PRINT "[211]OLUTION [210]EADER PROGRAM ALSO ON THE"
90 PRINT "DISK). [212]HIS PROGRAM TAKES ABOUT 2 HOURS"
100 PRINT "AND 15 MINUTES TO RUN ON A 1 [205][200]Z [195]-64"
110 PRINT "AND THE SOLUTION FILE TAKES ABOUT 637"
120 PRINT "BLOCKS ON A DISK (THERE ARE 2808"
130 PRINT "SOLUTIONS).": PRINT
140 PRINT "[208]RESS [211][208][193][195][197] [194][193][210] TO CONTINUE.": PRINT: A$=""
150 GET A$: IF A$="" THEN 150
160 REMOPEN 8,DV,8,"0:SOLUTIONS,S,W":REM   REM THIS LINE IF DISK FILE NOT WANTED
170 SC=0: FOR O=-19 TO 19
180 FOR N=19 TO -19 STEP -1: IF N=O THEN 450
190 E=1-O-N: IF E<-19 OR E>19 OR E=O OR E=N THEN 450
200 T=10-E-N: IF T<-19 OR T>19 OR T=O OR T=N OR T=E THEN 450
210 I=9-N-N-E: IF I<-19 OR I>19 OR I=O OR I=N OR I=E OR I=T THEN 450
220 W=2-T-O: IF W<-19 OR W>19 OR W=O OR W=N OR W=E OR W=T OR W=I THEN 450
230 FOR L=-19 TO 19: IF L=O OR L=N OR L=E OR L=T OR L=I OR L=W THEN 440
240 V=11-E-L-E-E-N: IF V<-19 OR V>19 OR V=O OR V=N OR V=E OR V=T THEN 440
250 IF V=I OR V=W OR V=L THEN 440
260 IF T+W+E+L+V+E<>12 THEN 440
270 S=7-E-V-E-N: IF S<-19 OR S>19 THEN 440
280 IF S=E OR S=I OR S=L OR S=N OR S=O OR S=T OR S=V OR S=W THEN 440
290 X=6-S-I: IF X<-19 OR X>19 THEN 440
300 IF X=E OR X=I OR X=L OR X=N OR X=O OR X=T OR X=V OR X=W OR X=S THEN 440
310 F=5-I-V-E: IF F<-19 OR F>19 OR F=W OR F=X THEN 440
320 IF F=E OR F=I OR F=L OR F=N OR F=O OR F=S OR F=T OR F=V THEN 440
330 FOR R=19 TO -19 STEP -1: IF R=E OR R=F OR R=I OR R=L OR R=N THEN 430
340 IF R=O OR R=S OR R=T OR R=V OR R=W OR R=X THEN 430
350 H=3-T-R-E-E: IF H<-19 OR H>19 OR H=E OR H=F OR H=I OR H=L OR H=N THEN 430
360 IF H=O OR H=R OR H=S OR H=T OR H=V OR H=W OR H=X THEN 430
370 G=8-E-I-H-T: IF G<-19 OR G>19 OR G=E OR G=F OR G=H OR G=I OR G=L THEN 430
380 IF G=N OR G=O OR G=R OR G=S OR G=T OR G=V OR G=W OR G=X THEN 430
390 U=4-F-O-R: IF U<-19 OR U>19 OR U=E OR U=F OR U=G OR U=H OR U=I THEN 430
400 IF U=L OR U=N OR U=O OR U=R OR U=S OR U=T OR U=V OR U=W OR U=X THEN 430
410 SC=SC+1: PRINT SC;E;F;G;H;I;L;N;O;R;S;T;U;V;W;X: PRINT
420 REM PRINT#8,SC;E;F;G;H;I;L;N;O;R;S;T;U;V;W;X:REM REM LINE IF FILE NOT WANTED
430 NEXT R
440 NEXT L
450 NEXT N
460 NEXT O
470 CLOSE8
480 END
10000 D=PEEK(186):N$="FLOYD KIRK":OPEN15,D,15,"S0:"+N$:CLOSE15:SAVEN$,D:END